mirror of
https://github.com/Z3Prover/z3
synced 2025-04-07 09:55:19 +00:00
251527603d
This is a large rework of my first attempt at this (#459). This implementation calls into the recently implemented python scripts to generate the necessary generated ``.h`` and ``.cpp`` files but is independent from Python building system otherwise. Unlike the Python build system, the generated files are emitted into the build tree to avoid polluting the source tree. The build system is setup to refuse to configure if it detects generated files in the source tree. If your source tree is dirty you can run ``git clean -fx`` to clean your working directory. Currently the build succeeds on Linux using CMake 3.4.3 using the "Unix Makefiles" generator with gcc or clang. The following notable features are implemented: * Building of the C and C++ examples and the ``test-z3`` executable. These are included from the ``all`` target so you have to tell the build system (e.g. make) to build them manually. * Install (``make install``) and uninstall (``make uninstall``) of libz3 and its header files. This supports ``DESTDIR`` out of the box because CMake supports it. * An option (``BUILD_LIBZ3_SHARED``) to build libz3 as a static or dynamic library. * Support for using/not using OpenMP (``USE_OPENMP``) * Support for using/not using libgmp (``USE_LIB_GMP``) * Setting the SOVERSION for libz3. I'm not sure if I'm setting the * number correctly though. This is required by Linux distrubtions that wills ship libz3. This needs discussion. The following notable features are currently not implemented and are left for future work. * Support for ARM. * Support for the foci2 library. * Support for creating/installing/uninstalling the dotnet, java, python and ml bindings. * Full support for MSVC. Although I've tried to write the CMake code with MSVC in mind not all the correct flags are passed to it. * Support for using the git hash. This new build system has several advantages other the old build system. * It is easier for outside contributors to contribute to Z3 when the build system is something more standard. * Incremental builds work properly. With the old build system when new code is pulled down the old build directory would need to thrown out and a new fresh build had to be performed because the build system didn't know how to correctly rebuild the project (e.g. couldn't handle new sources being added/removed, compiler flags changing, generated files changing, etc...). This is a MASSIVE boost to productivity! * We now have access rich array of features that CMake provides for building C/C++ projects. This means less time spent implementing custom build system logic in Python that is already supported by CMake. * CMake supports many IDEs out of the box so it should be fairly straight forward to build Z3 with Visual Studio (once support for MSVC is added), Xcode, Eclipse CDT, CLion, ..etc.
65 lines
1.9 KiB
CMake
65 lines
1.9 KiB
CMake
# Tries to find an install of the GNU multiple precision library
|
|
#
|
|
# Once done this will define
|
|
# GMP_FOUND - BOOL: System has the GMP library installed
|
|
# GMP_INCLUDE_DIRS - LIST:The GMP include directories
|
|
# GMP_C_LIBRARIES - LIST:The libraries needed to use GMP via it's C interface
|
|
# GMP_CXX_LIBRARIES - LIST:The libraries needed to use GMP via it's C++ interface
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
|
|
# Try to find libraries
|
|
find_library(GMP_C_LIBRARIES
|
|
NAMES gmp
|
|
DOC "GMP C libraries"
|
|
)
|
|
if (GMP_C_LIBRARIES)
|
|
message(STATUS "Found GMP C library: \"${GMP_C_LIBRARIES}\"")
|
|
else()
|
|
message(STATUS "Could not find GMP C library")
|
|
endif()
|
|
find_library(GMP_CXX_LIBRARIES
|
|
NAMES gmpxx
|
|
DOC "GMP C++ libraries"
|
|
)
|
|
if (GMP_CXX_LIBRARIES)
|
|
message(STATUS "Found GMP C++ library: \"${GMP_CXX_LIBRARIES}\"")
|
|
else()
|
|
message(STATUS "Could not find GMP C++ library")
|
|
endif()
|
|
|
|
# Try to find headers
|
|
find_path(GMP_C_INCLUDES
|
|
NAMES gmp.h
|
|
DOC "GMP C header"
|
|
)
|
|
if (GMP_C_INCLUDES)
|
|
message(STATUS "Found GMP C include path: \"${GMP_C_INCLUDES}\"")
|
|
else()
|
|
message(STATUS "Could not find GMP C include path")
|
|
endif()
|
|
|
|
find_path(GMP_CXX_INCLUDES
|
|
NAMES gmpxx.h
|
|
DOC "GMP C++ header"
|
|
)
|
|
if (GMP_CXX_INCLUDES)
|
|
message(STATUS "Found GMP C++ include path: \"${GMP_CXX_INCLUDES}\"")
|
|
else()
|
|
message(STATUS "Could not find GMP C++ include path")
|
|
endif()
|
|
|
|
if (GMP_C_LIBRARIES AND GMP_CXX_LIBRARIES AND GMP_C_INCLUDES AND GMP_CXX_INCLUDES)
|
|
set(GMP_INCLUDE_DIRS "${GMP_C_INCLUDES}" "${GMP_CXX_INCLUDES}")
|
|
list(REMOVE_DUPLICATES GMP_INCLUDE_DIRS)
|
|
message(STATUS "Found GMP")
|
|
else()
|
|
message(STATUS "Could not find GMP")
|
|
endif()
|
|
|
|
# TODO: We should check we can link some simple code against libgmp and libgmpxx
|
|
|
|
# Handle QUIET and REQUIRED and check the necessary variables were set and if so
|
|
# set ``GMP_FOUND``
|
|
find_package_handle_standard_args(GMP DEFAULT_MSG GMP_INCLUDE_DIRS GMP_C_LIBRARIES GMP_CXX_LIBRARIES)
|